Vai al contenuto

Come utilizzare SEQUENZA in Excel

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO RISULTATO FINALE

    In questa guida vediamo come utilizzare SEQUENZA in Excel: la funzione che genera un elenco di numeri con una sola formula. Partiamo dalla numerazione più semplice, passiamo a righe e colonne, valore iniziale e passo, e arriviamo alla mappa dei posti di una sala, alle date di una rassegna e al calendario completo della rassegna con i film più votati.

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO DATE RASSEGNA

    Azioni come numerare righe, creare date a intervalli regolari o preparare una griglia: sono operazioni che di solito facciamo trascinando il quadratino di riempimento, oppure (ahimè) con colonne nascoste. Funzionano - ma il risultato è statico: se l'elenco si allunga dobbiamo trascinare di nuovo. Con SEQUENZA la numerazione si adatta da sola, ed è uno dei mattoni con cui costruisco i modelli più dinamici, compresi i calendari che trovi sul sito, come il calendario Excel 2026.

    Diciamo che non ha molto senso trascinare dati se usiamo SEQUENZA, in particolare se lavoriamo con le funzioni dinamiche di Excel 365. Io la uso molto se devo creare modelli finanziari, dato che permette di fare sequenze di date in maniera dinamica, risultando una funzione comoda e intuitiva. SEQUENZA è anche la funzione più adatta per scoprire il concetto di matrice, dato che un semplice =SEQUENZA(7) permette di introdurre il tema in modo comodo e intuitivo. L'altra funzione che penso funzioni bene in questi casi è MATR.CASUALE, però richiede un numero maggiore di argomenti.

    Se poi vuoi veramente sapere tutto ciò che c'è da sapere sulla funzione SEQUENZA, esiste addirittura un libro di Meni Porat dedicato al tema, chiamato Mastering Sequence.

    Come funziona SEQUENZA in Excel

    Gli argomenti di SEQUENZA, come li mostra Excel nella finestra Argomenti funzione, sono quattro:

    =SEQUENZA(Righe;[Colonne];[Inizio];[Passaggio])

    • Righe: quante righe generare
    • Colonne (facoltativo): quante colonne generare, 1 se lo lasciamo vuoto
    • Inizio (facoltativo): il primo numero, 1 se lo lasciamo vuoto
    • Passaggio (facoltativo): di quanto aumenta ogni numero rispetto al precedente, 1 se lo lasciamo vuoto

    Come creare una numerazione con SEQUENZA

    Nel foglio SEQUENZA_BASE partiamo dal caso più semplice: i numeri da 1 a 10.

    =SEQUENZA(10)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO SEQUENZA SEMPLICE

    Scriviamo la formula solo in B3 e Excel la espande sulle 10 righe sotto: è una matrice dinamica. Se proviamo a scrivere qualcosa in una di quelle celle, la formula restituisce #ESPANSIONE!, perché non ha più spazio.

    Come anticipato questo è il caso più tipico per iniziare a ragionare sul concetto di array - una sola funzione, semplice, permette di coprire un numero variabile di celle.

    Come generare righe e colonne nella sequenza

    Con il secondo argomento otteniamo una griglia. Potremmo inserire, ad esempio, quattro righe e cinque colonne:

    =SEQUENZA(4;5)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO RIGHE COLONNE

    Nota l'ordine: SEQUENZA riempie prima la riga, da sinistra a destra, poi passa alla riga successiva. Chiaramente in questo caso le celle sono 20 (4x5), ma non c'è un vero limite dimensionale.

    Se volessi avere una sequenza semplice ma solo in colonne separate, ad esempio da 1 a 10, basterebbe fare:

    =SEQUENZA(;10)

    Come scegliere il valore iniziale e il passo per sequenza

    Con gli ultimi due argomenti decidiamo da dove partire e di quanto aumentare. Partiamo da 10 e vogliamo uno step di 10 per 5 valori in totale, creando un array tipo questo: 10|20|30|40|50

    La formula è:

    =SEQUENZA(5;1;10;10)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO INIZIO PASSAGGIO

    Il passo può essere anche negativo - per contare all'indietro - oppure decimale, ad esempio 0,5.

    Come creare la mappa dei posti di una sala con SEQUENZA

    Ora usiamo due SEQUENZA insieme per creare una mappatura alfanumerica - potenzialmente potresti usare la stessa tecnica per realizzare una scacchiera, ad esempio.

    Fingiamo che in una sala cinema ci siano 8 file, dalla A alla H, con 12 posti ciascuna (96 celle, 8x12). Nel foglio POSTI_SALA:

    =CODICE.CARATT(64+SEQUENZA(8))&SEQUENZA(1;12)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO POSTI SALA
    • SEQUENZA(8) genera i numeri da 1 a 8 in colonna; sommando 64 otteniamo i codici da 65 a 72, che CODICE.CARATT trasforma nelle lettere dalla A alla H. In particolare 65 = A, 66 = B e così via
    • SEQUENZA(1;12) genera i numeri da 1 a 12 in una riga
    • unendo una colonna e una riga con &, Excel combina ogni lettera con ogni numero e crea una griglia di 8 righe per 12 colonne

    Il risultato va da A1 a H12: 96 posti con una formula. Non è legato a SEQUENZA ma, se volessi fare il percorso inverso (tipo trovare il codice corretto per A), useresti la funzione UNICODE. =UNICODE("A") fa infatti 65.

    Come creare un elenco di date con SEQUENZA

    Le date in Excel sono numeri, quindi SEQUENZA funziona anche con loro. Nel foglio DATE_RASSEGNA scriviamo nella cella gialla C2 il primo Martedì di una rassegna, il 13/01/2026, e generiamo le otto serate, una a settimana per i martedì seguenti:

    =SEQUENZA(8;1;C2;7)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO DATE RASSEGNA

    Il valore iniziale è la data in C2 e il passo è 7, cioè una settimana. La rassegna va dal 13 Gennaio al 3 Marzo 2026. Ricordati di dare alle celle il formato data, altrimenti vedrai i numeri seriali delle date, come 46035. Se cambiamo la data in C2, tutte le serate si spostano.

    Qui entrano in gioco potenzialmente due funzioni molto interessanti:

    • DATA.MESE(data_iniziale;mesi) restituisce il giorno del mese ricavato dalla data iniziale, aggiungendo un certo numero di mesi. Per esempio, DATA.MESE(13/01/2026;3) restituisce 13/04/2026
    • FINE.MESE(data_iniziale;mesi) restituisce invece la fine del mese considerato, anche se ha un meccanismo simile. Ad esempio, FINE.MESE(13/01/2026;3) restituisce 30/04/2026

    Se tu volessi fare una sequenza di date che prenda il 13 di tutti i prossimi 12 mesi partendo dal 13 Gennaio 2026 compreso (inserito in C2), potresti fare:

    =DATA.MESE(C2;SEQUENZA(13;;0))

    Meglio ancora, potresti ottenere i valori di fine mese usando proprio FINE.MESE:

    =FINE.MESE(C2;SEQUENZA(13;;0))

    FORMAZIONE EXCEL

    Vuoi portare queste competenze nel tuo team?

    Progetto percorsi di formazione Excel basati sui vostri obiettivi, sul livello dei partecipanti e sui casi che affrontate realmente in azienda.

    MARCO FILOCAMO SQUARE 100 PNG

    Marco Filocamo · Microsoft Excel MVP

    Hai invece un file o un processo specifico da migliorare? Scopri la consulenza Excel →

    Come numerare un elenco dinamico con SEQUENZA

    Un uso molto pratico è numerare un elenco che cambia lunghezza. Lavoriamo con la tabella TBL_FILM: il catalogo di una piattaforma di streaming con 27 film, con titoli, anni, registi e durate reali, mentre noleggi e voti sono inventati.

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO DATABASE PARTENZA

    Nel foglio CLASSIFICA_NUMERATA ordiniamo i film per noleggi e li numeriamo:

    =SEQUENZA(RIGHE(TBL_FILM))

    =DATI.ORDINA.PER(TBL_FILM[FILM];TBL_FILM[NOLEGGI];-1)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO CLASSIFICA NUMERATA

    RIGHE conta le righe della tabella (27) e SEQUENZA genera i numeri da 1 a 27. Se aggiungiamo un film alla tabella, sia la classifica sia la numerazione si allungano da sole - niente più numeri da trascinare.

    Un'alternativa poteva essere calcolare SEQUENZA solo successivamente, ad esempio realizzare in C3 l'elenco e poi:

    =SEQUENZA(CONTA.VALORI(C3#))

    Come creare il calendario di una rassegna con SEQUENZA

    Mettiamo insieme tutto per il risultato finale: una rassegna di otto serate, ogni Martedì, con gli otto film più votati dagli utenti. Nel foglio RASSEGNA_MARTEDI numeriamo le serate, generiamo le date e prendiamo i film:

    =SEQUENZA(8)

    =SEQUENZA(8;1;C2;7)

    =INCLUDI(DATI.ORDINA.PER(SCEGLI.COL(TBL_FILM;1;7);TBL_FILM[VOTO];-1);8)

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO RASSEGNA MARTEDI
    • la prima formula numera le serate da 1 a 8
    • la seconda genera le date, una a settimana, partendo dal Martedì in C2
    • la terza prende FILM e VOTO con SCEGLI.COL, li ordina per voto dal più alto con DATI.ORDINA.PER e tiene i primi 8 con INCLUDI

    La rassegna parte il 13/01/2026 con Rocky (voto 4,9), prosegue con Titanic e Joker e si chiude il 3 Marzo con Jurassic Park. Se cambiano i voti o la data di partenza, tutto il calendario si aggiorna.

    Idealmente, inseriresti poi 8 in una cella per rendere tutto dinamico, ma in questo caso lo fissiamo nella formula.

    Come trovare i valori mancanti di una sequenza con SEQUENZA

    Mettiamo che vogliamo controllare quali siano gli anni mancanti nella nostra TBL_FILM, in modo da verificare quali film acquistare per avere almeno un film per ogni anno dal primo all'ultimo fra quelli presenti.

    Potremmo risolvere così:

    =LET(anno;TBL_FILM[ANNO];
    seq;SEQUENZA(MAX(anno)-MIN(anno)+1;;MIN(anno));
    FILTRO(
    seq;
    VAL.NON.DISP(CONFRONTA.X(seq;anno));
    "Nessun anno mancante"
    )
    )

    COME UTILIZZARE SEQUENZA MICROSOFT EXCEL MARCOFILOCAMO ANNI MANCANTI

    In pratica stiamo dicendo che:

    • Vogliamo gli anni, possiamo anche evitare di rimuovere i duplicati con UNICI, potenzialmente
    • Creiamo una sequenza di numeri che vada dal più piccolo al più grande, considerandoli tutti
    • FILTRO ci permette di mettere a confronto questa sequenza con tutti i possibili valori precedenti, utilizzando CONFRONTA.X. In pratica stiamo verificando se ciascuno di questi valori sequenziali esista, altrimenti avremo un errore. Serve proprio a questo VAL.NON.DISP, che ci restituisce esclusivamente quelli mancanti

    Ancora più elegante, se vogliamo essere precisi, sarebbe una formula come questa:

    =LET(anni;TBL_FILM[ANNO];tutti_gli_anni;SEQUENZA(MAX(anni)-MIN(anni)+1;;MIN(anni));anni_mancanti;FILTRO(tutti_gli_anni;VAL.NON.DISP(CONFRONTA.X(tutti_gli_anni;anni));"Nessun anno mancante");anni_mancanti)

    Conclusioni

    Abbiamo visto come utilizzare SEQUENZA in Excel per numerare, creare griglie, scegliere valore iniziale e passo, generare date e costruire, insieme ad altre funzioni, il calendario di una rassegna.

    Ti consiglio di sperimentare SEQUENZA sui tuoi file, oltre a usarla, perchè no, per spiegare anche ad altri come funzionino i dynamic array!

    Lascia un commento

    Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *

    Marco Filocamo
    Panoramica privacy

    This website uses cookies so that we can provide you with the best user experience possible. Cookie information is stored in your browser and performs functions such as recognising you when you return to our website and helping our team to understand which sections of the website you find most interesting and useful.