In questa guida vediamo come calcolare i giorni lavorativi in Excel e come gestire le scadenze: quanti giorni lavorativi ci sono tra due date, quale sarà la data di consegna dopo un certo numero di giorni, come considerare le festività italiane e le settimane di sei giorni, come calcolare le scadenze "fine mese" e come costruire un piano di produzione che si aggiorna da solo.

In breve: per contare i giorni lavorativi tra due date si usa GIORNI.LAVORATIVI.TOT(Data_iniziale;Data_finale;Vacanze), dove Vacanze è l'elenco delle festività mentre per trovare la data dopo un certo numero di giorni lavorativi si usa GIORNO.LAVORATIVO. Le versioni .INTL permettono di scegliere i giorni di riposo, ad esempio solo la Domenica, per casi più curiosi e avanzati.
Le operazioni con le date sono curiose in Excel, ad esempio sottrarre due date è facile - visto che sono due numeri, per Excel, basta un meno, come spiego nella guida su come fare una sottrazione in Excel. Lavorare però con funzioni come queste, oltre a casi come DATA.MESE / FINE.MESE e così via, può essere utile per numerosi casi, non solo per chi lavora in HR (che è il caso tipico).
Vediamo quindi come impostare al meglio un file per risolvere problemi tipici relativi a sequenze con dei "buchi" in mezzo, come ad esempio festività e fine settimana.
Come preparare l'elenco delle festività in Excel
Lavoriamo sul piano di produzione di un film immaginario, che si gira e si monta nel 2027.
Prima di tutto, nel foglio FESTIVITA prepariamo la tabella TBL_FESTIVITA con le festività nazionali italiane del 2027: Capodanno, Epifania, Pasqua e Lunedì dell'Angelo, 25 Aprile, 1° Maggio, 2 Giugno, Ferragosto, Ognissanti, Immacolata, Natale e Santo Stefano. Le colonne sono solo due e chiaramente ci serve la prima, per i calcoli successivi.

Tenere le festività in una tabella è il trucco che rende comode tutte le formule della guida: basta scrivere TBL_FESTIVITA[DATA] e, se aggiungiamo una data, ad esempio la festa del patrono della città, tutte le formule la considerano da sole.
Come sempre, è un'ottima idea usare le tabelle in Excel proprio per tenere tutto ordinato e creare sistemi ripetibili.
Come calcolare la data della Pasqua in Excel
Quasi tutte le festività cadono sempre lo stesso giorno, tranne la Pasqua e il Lunedì dell'Angelo. Nel foglio CALCOLARE_PASQUA scriviamo l'anno in C2 e usiamo una formula piuttosto conosciuta tra chi lavora con Excel:

=ARROTONDA.DIFETTO(DATA(C2;5;GIORNO(MINUTO(C2/38)/2+56));7)-34
Per il 2027 il risultato è il 28/03/2027: il Lunedì dell'Angelo è il giorno dopo, =C3+1. Non serve capire tutti i passaggi: è una scorciatoia matematica del calcolo della Pasqua, che ho trovato su questo sito dedicato.

A quanto pare, non funziona correttamente per l'anno 2079 - ma ho verificato che c'è un'altra soluzione, corretta pure per il 2079, che sarebbe questa:
=LET(
anno;C2;
secolo;INT(anno/100);
correzioneLuna;15+INT((3*secolo+3)/4)-INT((8*secolo+13)/25);
correzioneSole;2-INT((3*secolo+3)/4);
ciclo;RESTO(anno;19);
epatta;RESTO(19*ciclo+correzioneLuna;30);
eccezione;INT(epatta/29)+(INT(epatta/28)-INT(epatta/29))*INT(ciclo/11);
giornoPasqua;21+epatta-eccezione;
domenica;7-RESTO(anno+INT(anno/4)+correzioneSole;7);
scarto;7-RESTO(giornoPasqua-domenica;7);
DATA(anno;3;giornoPasqua+scarto)
)
Anche questa formula l'ho trovata online qui e riadattata, a quanto pare è l'algoritmo gregoriano di Lichtenberg ma la spiegazione stessa dell'algoritmo è piuttosto convulsa. Ci fidiamo.
Come contare i giorni lavorativi tra due date in Excel
La prima domanda è: quanti giorni lavorativi ci sono tra due date? Gli argomenti di GIORNI.LAVORATIVI.TOT, come li mostra Excel nella finestra Argomenti funzione, sono tre:
=GIORNI.LAVORATIVI.TOT(Data_iniziale;Data_finale;[Vacanze])
- Data_iniziale e Data_finale: il periodo da considerare, estremi compresi
- Vacanze (facoltativo): l'elenco delle festività da escludere

Nel foglio GIORNI_TRA_DATE le riprese vanno dal 01/03/2027 al 30/04/2027. I giorni di calendario sono 61, con =C3-C2+1. I giorni lavorativi, dal lunedì al venerdì:
=GIORNI.LAVORATIVI.TOT(C2;C3)
Il risultato è 45. Ora togliamo anche le festività, con il terzo argomento:

=GIORNI.LAVORATIVI.TOT(C2;C3;TBL_FESTIVITA[DATA])
I giorni scendono a 44: nel periodo c'è il Lunedì dell'Angelo, il 29 Marzo. Il 25 Aprile invece nel 2027 cade di domenica, quindi non cambia il conteggio.
Chiaramente puoi simulare i calcoli con qualsiasi anno, non solo per il 2027.
Come calcolare una data dopo un certo numero di giorni lavorativi in Excel
Vediamo ora la domanda opposta: se il montaggio inizia il 01/03/2027 e servono 40 giorni lavorativi, quando finisce?
Per questo c'è GIORNO.LAVORATIVO, con gli argomenti Data_iniziale, Giorni e Vacanze. Nel foglio DATA_CONSEGNA:

=GIORNO.LAVORATIVO(C2;C3;TBL_FESTIVITA[DATA])
Senza festività la data sarebbe il 26/04/2027, con le festività diventa il 27/04/2027. Attenzione a come conta GIORNO.LAVORATIVO: parte dal giorno dopo la data iniziale. Se la data iniziale è il primo giorno di lavoro e vuoi la data dell'ultimo giorno, devi togliere 1 ai giorni - lo vedremo nel piano di produzione.
FORMAZIONE EXCEL
Vuoi portare queste competenze nel tuo team?
Progetto percorsi di formazione Excel basati sui vostri obiettivi, sul livello dei partecipanti e sui casi che affrontate realmente in azienda.

Marco Filocamo · Microsoft Excel MVP
Hai invece un file o un processo specifico da migliorare? Scopri la consulenza Excel →
Come contare i giorni lavorativi quando si lavora anche il sabato in Excel
E se la settimana lavorativa avesse sei giorni? Sul set spesso si lavora anche il sabato. Per questi casi possiamo sfruttare le versioni .INTL delle due funzioni, che hanno un argomento in più per scegliere i giorni di riposo:
=GIORNI.LAVORATIVI.TOT.INTL(Data_iniziale;Data_finale;[Festivi];[Vacanze])
Il punto su cui fare attenzione sono i nomi degli argomenti in italiano: Festivi indica i giorni di riposo della settimana, cioè il fine settimana, mentre Vacanze è l'elenco delle festività, come nelle altre funzioni. Nel foglio SEI_GIORNI usiamo il codice 11, che vuol dire "solo la domenica è di riposo":

=GIORNI.LAVORATIVI.TOT.INTL(C2;C3;11;TBL_FESTIVITA[DATA])
Dal 01/03/2027 al 30/04/2027 i giorni di lavoro passano da 44 a 52, perché si aggiungono gli otto sabati del periodo.
Come scegliere i giorni di riposo con un testo in Excel
Al posto del codice possiamo scrivere un testo di sette cifre, una per giorno da lunedì a domenica: 0 è un giorno di lavoro, 1 un giorno di riposo. "0000001" vuol dire di nuovo "si riposa solo la domenica":

=GIORNI.LAVORATIVI.TOT.INTL(C2;C3;"0000001";TBL_FESTIVITA[DATA])
Il risultato è lo stesso, 52, ma con il testo possiamo descrivere qualsiasi settimana, ad esempio "1000001" per chi riposa domenica e lunedì. Sono casi un po' limite ma potrebbero tornare utili, ad esempio se volessi concatenare uno schedule di una singola persona che ha inserito i dati in una tabella dedicata.
Come calcolare una data con la settimana di sei giorni in Excel
Lo stesso vale per GIORNO.LAVORATIVO.INTL. Con 40 giorni di riprese dal lunedì al sabato, a partire dal 01/03/2027:

=GIORNO.LAVORATIVO.INTL(C2;40;11;TBL_FESTIVITA[DATA])
Le riprese finiscono il 17/04/2027, dieci giorni prima rispetto alla settimana di cinque giorni. Se poi volessimo fare le cose davvero per bene, non inseriresti 40 ma avresti una cella dedicata nella quale fare qualche simulazione, per esempio se avessi persone coinvolte che hanno anche altri impegni.
Come calcolare le scadenze di fine mese in Excel
Quando scade una fattura pagata a 30 giorni fine mese? Le fatture dei fornitori si pagano spesso "a 30 giorni fine mese", cioè alla fine del mese successivo a quello della fattura. Qui serve FINE.MESE, che ha due argomenti: Data_iniziale e Mesi. Nel foglio SCADENZE_FORNITORI:

=FINE.MESE(C3;1)
La fattura di Luci e Riflessi Srl del 18/01/2027 scade il 28/02/2027, l'ultimo giorno di Febbraio. Per i 60 giorni fine mese basta scrivere 2 al posto di 1 e così via. In questo caso non stiamo usando alcuna regola di giorno lavorativo ed è anche il caso più comune, almeno per la mia esperienza.
Come spostare la scadenza al primo giorno lavorativo in Excel
Vediamo un caso più complesso: se la scadenza precedente cadesse di sabato, di domenica o in una festività, il pagamento slitterebbe al primo giorno lavorativo. Lo otteniamo partendo dal giorno prima della scadenza e chiedendo il primo giorno lavorativo successivo:

=GIORNO.LAVORATIVO(F3-1;1;TBL_FESTIVITA[DATA])
Se la scadenza è già un giorno lavorativo, resta la stessa. Se non lo è, si sposta: la fattura di Montaggio Digitale Srl scade a 60 giorni il 31/07/2027, che è un sabato: il pagamento passa a lunedì 02/08/2027.
Come creare un piano di produzione con i giorni lavorativi in Excel
Questo è un caso tipicio abbastanza intricato in Excel - come costruiamo un piano in cui ogni fase parte dopo la precedente? Mettiamo insieme tutto per il risultato finale: un piano in cui ogni fase inizia il giorno lavorativo dopo la fine della precedente. Nel foglio PIANO_PRODUZIONE scriviamo in C2 la data di inizio, il 01/02/2027. Per ogni fase indichiamo la durata in giorni lavorativi. La fine di ogni fase è:
=GIORNO.LAVORATIVO(D5;C5-1;TBL_FESTIVITA[DATA])
Togliamo 1 ai giorni perché il primo giorno della fase conta già come giorno di lavoro. L'inizio di ogni fase successiva è il primo giorno lavorativo dopo la fine della precedente:

=GIORNO.LAVORATIVO(E5;1;TBL_FESTIVITA[DATA])
La preparazione del set dura 10 giorni, dal 01/02/2027 al 12/02/2027, le riprese in esterni iniziano lunedì 15/02/2027 e così via fino alla consegna della copia, che termina il 19/07/2027. Se cambiamo la data di inizio o la durata di una fase, tutte le date successive si spostano, saltando weekend e festività.
Se vogliamo alzare l'asticella, possiamo crearla come funzione matriciale, anche se è più complessa:

In questo caso la formula diventa:
=LET(giorni;TBL_FASI[GIORNI];
base;GIORNO.LAVORATIVO(C2;-1;TBL_FESTIVITA[DATA]);
cumulati;SCAN(0;giorni;SOMMA);
finale;STACK.ORIZ(GIORNO.LAVORATIVO(base;cumulati-giorni+1;TBL_FESTIVITA[DATA]);GIORNO.LAVORATIVO(base;cumulati;TBL_FESTIVITA[DATA]));
finale)
Dovendo lavorare in maniera ricorsiva, possiamo selezionare i giorni lavorativi ignorando le festività e poi, usando GIORNO.LAVORATIVO, creare un array di due colonne per riportare i dati in un colpo solo.
Conclusioni
Abbiamo visto come calcolare i giorni lavorativi in Excel: contarli tra due date con GIORNI.LAVORATIVI.TOT, trovare una data futura con GIORNO.LAVORATIVO, gestire settimane diverse con le versioni .INTL, calcolare le scadenze con FINE.MESE e costruire un piano di produzione completo.
Il consiglio è di tenere sempre le festività in una tabella - è la parte che si dimentica più spesso - e di aggiornarla ogni anno con la nuova data della Pasqua. Se ti serve anche un calendario da stampare, trovi la guida su come creare un calendario in Excel, mentre per le assenze del personale c'è quella su come creare un piano ferie in Excel.
Prova a costruire con GIORNO.LAVORATIVO il piano del tuo prossimo progetto: quando una fase slitta, tutte le date si spostano da sole!
