Un grafico a mappa in Excel può essere creato in pochi passaggi: servono una colonna geografica, una colonna con i valori, selezionare le due colonne e cliccare sul comando Inserisci > Mappe > Mappa colorata.
Il grafico standard è utile, ma lascia poco controllo quando vogliamo filtrare i dati o modificare in modo più deciso il suo aspetto. Il default, fra l'altro, considera l'intero mondo (se usiamo le nazioni) e quindi può risultare veramente difficile da leggere. Per fortuna, si possono selezionare solo i Paesi con dei dati, ma ci sono alcuni passaggi da fare.
In questa guida vediamo come costruire una soluzione più articolata. Partiremo dalla tabella TBL_PROFICIENCY, che contiene il livello di competenza nell'uso dell'inglese dei Paesi presenti nel file, ottenuti da una statistica EF, e arriveremo a un grafico che:
- permette di scegliere un livello da un menu a discesa;
- evidenzia soltanto i Paesi appartenenti al livello selezionato;
- mantiene visibili gli altri Paesi con un colore neutro;
- mostra le etichette soltanto sui valori effettivi;
- utilizza una scala colori e uno stile personalizzati.
La parte interessante non è quindi solo l'inserimento della mappa, ma anche la struttura dati preparata prima del grafico.
L'idea iniziale per questa guida partiva da una domanda: "Parliamo tutti di AI, LLM, Copilot e, in generale, con termini inglesi. Noi Italiani come ce la caviamo, confrontati con altre nazioni?" Beh, male, siamo 34esimi su 36 Paesi analizzati in Europa, battiamo giusto Turchia e Azerbaigian. Ma torniamo alla guida.
NB: In questa guida non parlerò delle mappe 3D, anche se esistono in Excel, perchè seguono regole diverse.
Come preparare i dati per un grafico a mappa in Excel
Strutturare la tabella con Paesi e punteggi
Nel foglio TBL_PROFICIENCY troviamo una tabella Excel con lo stesso nome. Questa è la base necessaria per creare il grafico geografico e alimentare il filtro dinamico.
Le colonne necessarie per costruire il grafico sono queste:
| Colonna | Contenuto |
|---|---|
| PROFICIENCY | fascia di competenza, per esempio Moderate proficiency |
| COUNTRY | nome del Paese riconosciuto da Excel |
| SCORE | punteggio numerico da rappresentare sulla mappa |
| FINAL | numero usato per ordinare correttamente le fasce nel menu più facilmente |
Le colonne FLAG e FLAG_IMG presenti nel file non sono necessarie per creare il grafico a mappa, ma possono essere utili se vuoi fare invece altri esperimenti dinamici e visuali. La tabella contiene 36 Paesi. Nell'analisi EF c'era anche una riga dedicata alla Russia, ma l'ho rimossa da TBL_PROFICIENCY, anche perchè occupa moltissimo spazio.
Un dettaglio importante: il grafico a mappa in Excel funziona meglio se i dati sono in inglese e vanno eseguiti alcuni adattamenti, ad esempio il nome internazionale per la Turchia (Türkiye) non è riconosciuto, funziona bene invece Turkey. Lo stesso con i codici nazione: benchè ci sia SK per Slovacchia, il rischio è di trovarsi con SK = South Korea (Corea del Sud). Fai sempre delle prove prima di poi caricare i dati.
Un esempio utile di utilizzo è, ad esempio, fatturato per regione - quando lavoravo in consulenza, dovevo fare spesso questi grafici e le alternative non erano entusiasmanti (ad esempio colorare diversamente dei PowerPoint).
Creare un grafico a mappa standard in Excel
Prima di costruire la versione dinamica, creiamo il grafico a mappa standard presente nel foglio TBL_PROFICIENCY.
- Seleziona le colonne COUNTRY e SCORE, senza le intestazioni.
- Apri la scheda Inserisci.
- Seleziona Mappe.
- Scegli Mappa colorata.
Nel file, l'intervallo corrisponde a D2:E38 - ma avendo le tabelle, prenderà TBL_PROFICIENCY[[COUNTRY]:[SCORE]]. Excel interpreta la prima colonna come informazione geografica e utilizza la seconda per assegnare un colore a ciascuna area. I punteggi più alti ricevono una tonalità diversa rispetto ai valori più bassi.
Il grafico semplice è sufficiente quando vogliamo rappresentare tutti i dati senza interazioni, ma a noi interessa creare un elenco dinamico per valutare come siano composti i macro-blocchi per singola proficiency. Qui ho inserito due esempi, ma il senso è lo stesso - che siano valori da 1 a 4 o quelli numerici, i risultati sono simili.
Se filtrassimo direttamente la tabella, i Paesi esclusi scomparirebbero. Excel adatterebbe inoltre l'area visibile ai dati rimasti. Il risultato cambierebbe forma a ogni selezione e sarebbe più difficile confrontare le diverse fasce. Certo, potremmo dire al grafico di non cambiare
Per evitarlo, nel grafico finale manterremo sempre tutti i Paesi nell'origine dati.
Come creare il filtro dinamico per la mappa
Creare l'elenco dinamico delle fasce
Nel foglio LIST viene creato l'elenco utilizzato dal menu a discesa.
Nella cella D3 inserisci questa formula:
=STACK.VERT("<>";UNICI(DATI.ORDINA.PER(TBL_PROFICIENCY[PROFICIENCY];TBL_PROFICIENCY[FINAL];1)))
La formula esegue tre operazioni:
- DATI.ORDINA.PER ordina le fasce usando la colonna FINAL (che sono i numeri da 1 a 4);
- UNICI mantiene una sola occorrenza di ogni fascia;
- STACK.VERT aggiunge il valore <> in cima all'elenco.
Nel file, <> indica che non deve essere applicato alcun filtro. È una scelta tecnica: puoi leggerlo come Tutte le fasce e funziona bene se devi fare delle somme condizionate con dei filtri, dato che prende tutti i valori per una certa cella.
Il risultato è un array composto da <>, seguito dalla capacità in inglese (Proficiency), dai Paesi peggiori ai migliori.
Come detto, la colonna FINAL serve soltanto a mantenere questo ordine (da 1 a 4). Se adatti la procedura a un altro database, puoi sostituirla con una piccola tabella di ordinamento esplicita.
Per spiegare meglio il punto di FINAL:
=CONTA.VALORI(ESCLUDI(UNICI(TBL_PROFICIENCY[[#Intestazioni];[PROFICIENCY]]:[@PROFICIENCY]);1))
In pratica UNICI prende i valori univoci a partire dall'intestazione della colonna chiamata Proficiency fino alla riga corrente. CONTA.VALORI li conta tutti, ma ne togliamo uno con ESCLUDI, che sarebbero le intestazioni. In questo modo abbiamo i numeri da 1 a 4, solo perchè abbiamo già ordinato i dati dal più piccolo al più grande. Diciamo che è un buon workaround, in questo caso, ma da utilizzare con attenzione.
La convalida dati non sempre gestisce bene un riferimento a matrice dinamica collocato in un altro foglio. Nel file viene quindi utilizzato un nome definito.
- Apri Formule > Gestione nomi.
- Seleziona Nuovo.
- Inserisci come nome: LIST_PROFICIENCY
- Nel campo Riferito a inserisci:
=LIST!$D$3#
Il simbolo # richiama l'intera matrice generata dalla formula inserita in D3.
Nel foglio GRAFICO_MAPPA, la cella B3 contiene la selezione dell'utente.
- Seleziona B3.
- Apri Dati > Convalida dati.
- In Consenti, scegli Elenco.
- In Origine, inserisci:
=LIST_PROFICIENCY
- Conferma con OK.
A questo punto puoi scegliere una singola fascia oppure <> per visualizzare tutti i Paesi.
Come creare l'origine dati dinamica del grafico a mappa
Nel foglio GRAFICO_MAPPA, inseriamo le intestazioni:
- B5: NAZIONE;
- C5: PUNTEGGIO;
- D5: POS.
La formula principale viene inserita in B6 e restituisce due colonne: Paese e valore da usare nella mappa.
=SE(
B3="<>";
STACK.ORIZ(TBL_PROFICIENCY[COUNTRY];TBL_PROFICIENCY[SCORE]);
LET(
intervallo;
FILTRO(
STACK.ORIZ(TBL_PROFICIENCY[COUNTRY];TBL_PROFICIENCY[SCORE]);
TBL_PROFICIENCY[PROFICIENCY]=B3
);
altri_dati;
FILTRO(
STACK.ORIZ(
TBL_PROFICIENCY[COUNTRY];
TBL_PROFICIENCY[SCORE]/TBL_PROFICIENCY[SCORE]+99
);
TBL_PROFICIENCY[PROFICIENCY]<>B3
);
finale;
STACK.VERT(intervallo;altri_dati);
finale
)
)
Vediamola per blocchi.
Mostrare tutti i Paesi sulla mappa
La prima parte controlla il valore selezionato in B3:
SE(B3="<>";STACK.ORIZ(TBL_PROFICIENCY[COUNTRY];TBL_PROFICIENCY[SCORE]);...)
Quando è selezionato <>, la formula restituisce direttamente tutti i Paesi e tutti i punteggi. STACK.ORIZ affianca le due colonne della tabella e produce l'intervallo che alimenterà il grafico.
Filtrare i Paesi in base al livello selezionato
La variabile intervallo mantiene i punteggi reali soltanto per le righe che rispettano la selezione:
intervallo;
FILTRO(
STACK.ORIZ(TBL_PROFICIENCY[COUNTRY];TBL_PROFICIENCY[SCORE]);
TBL_PROFICIENCY[PROFICIENCY]=B3
)
Ad esempio: se selezioniamo Moderate proficiency, il risultato contiene i Paesi di quella fascia con i rispettivi punteggi.
Mantenere visibili i Paesi esclusi dal filtro
La variabile altri_dati recupera invece tutti i Paesi che non appartengono alla fascia scelta:
altri_dati;
FILTRO(
STACK.ORIZ(
TBL_PROFICIENCY[COUNTRY];
TBL_PROFICIENCY[SCORE]/TBL_PROFICIENCY[SCORE]+99
);
TBL_PROFICIENCY[PROFICIENCY]<>B3
)
Il punto cruciale è questa espressione:
TBL_PROFICIENCY[SCORE]/TBL_PROFICIENCY[SCORE]+99
Ogni punteggio viene diviso per sé stesso. Il risultato è sempre 1, che sommato a 99 restituisce 100. Potremmo essere tentati di scrivere direttamente 100, ma ci serve una matrice con la stessa altezza della colonna SCORE. Utilizzando la divisione, otteniamo un valore 100 per ogni riga.
In pratica, i Paesi non selezionati restano nell'origine del grafico, ma ricevono tutti un valore artificiale pari a 100. Questo è necessario, o almeno mi pareva la scelta migliore, perchè altrimenti le nazioni vengono tutte rimosse dal grafico e non si riescono a capire bene i macro-blocchi a livello di proficiency.
Unire i punteggi reali e i valori neutri
L'ultima parte impila i Paesi selezionati e quelli esclusi:
finale;STACK.VERT(intervallo;altri_dati)
La formula restituisce sempre tutte le 36 nazioni presenti nella tabella. Cambiano soltanto i valori:
- punteggio reale per i Paesi della fascia scelta;
- valore 100 per tutti gli altri.
È questo accorgimento che impedisce alla mappa di cambiare area quando modifichiamo il filtro.
Vedi qui un esempio con High Proficiency, con i valori esclusivamente per i Paesi di questa fascia specifica.
Contare i Paesi evidenziati nella mappa
La cella C3 mostra il numero di Paesi che mantengono un punteggio reale.
=CONTA.SE(INDICE(B6#;0;2);">100")
B6# rappresenta l'intera matrice dinamica. INDICE recupera la seconda colonna e CONTA.SE conta soltanto i valori superiori a 100.
Quando scegliamo una fascia, i valori artificiali vengono esclusi dal conteggio. Se selezioniamo <>, tutti i punteggi sono superiori a 100 e il risultato è 36.
Calcolare la posizione dei Paesi con RANGO.UG
La colonna POS non è necessaria per la mappa, ma può essere utile come informazione di supporto.
In D6 troviamo:
=SE.ERRORE(RANGO.UG(INDICE(B6#;0;2);TBL_PROFICIENCY[SCORE]);"")
La formula confronta i valori presenti nella matrice con l'intera colonna SCORE e restituisce la posizione di ciascun Paese.
Nel grafico finale vengono utilizzate soltanto le colonne NAZIONE e PUNTEGGIO.
Come creare e personalizzare il grafico a mappa dinamico
Creare la mappa dall'intervallo dinamico
Ora possiamo creare il grafico a mappa dinamico usando l'intervallo preparato nel foglio GRAFICO_MAPPA.
- Seleziona B5:C41.
- Apri Inserisci > Mappe.
- Seleziona Mappa colorata.
- Sposta e ridimensiona il grafico.
Nel file il grafico occupa indicativamente l'area compresa tra E2 e AE42. Una dimensione ampia è importante perché le etichette abbiano spazio sufficiente.
Non stiamo collegando il grafico a un intervallo che cambia altezza. L'origine contiene sempre 36 righe: per questo il grafico resta stabile quando scegliamo una fascia diversa.
Configurare l'area geografica della mappa
Fai doppio clic su una zona della mappa per aprire il riquadro Formato serie dati.
Nelle Opzioni serie imposta:
- Proiezione mappa: Automatica;
- Area mappa: Solo aree con dati;
- Etichette mappa: Nessuna.
Le etichette geografiche di Excel vengono disattivate perché nel grafico finale mostreremo i punteggi, non i nomi dei Paesi.
La scelta Solo aree con dati mantiene il grafico concentrato sui Paesi presenti nell'intervallo. Poiché la formula conserva sempre tutte le nazioni, l'inquadratura non cambia tra una fascia e l'altra. Se avessimo detto Automatica, avremmo avuto una mappa del mondo, poco utile in questo caso. Questo è anche il motivo per il quale ho rimosso la Russia, che ha una dimensione enorme.
Personalizzare i colori del grafico a mappa
La mappa finale utilizza valori numerici. Questo ci permette di modificare la sezione Colore serie.
- Nel riquadro Formato serie dati, apri Opzioni serie.
- Nella sezione Colore serie, scegli Divergente (3 colori).
- Imposta i colori in questo modo:
| Posizione | Impostazione | Colore |
| Minimo | Numero: 400 | #F2F2F2 |
| Punto medio | Automatico | #FFC000 |
| Massimo | Automatico | #196B24 |
Il valore minimo impostato a 400 è superiore al valore artificiale 100. Di conseguenza, tutti i Paesi esclusi assumono il colore minimo, cioè un grigio molto chiaro. I punteggi reali del file sono invece compresi tra 454 e 624. Questi valori vengono distribuiti tra il giallo del punto medio e il verde scuro del massimo.
In pratica, la formattazione trasforma il valore 100 in uno stato visivo neutro, senza rimuovere il Paese dalla mappa.
La visualizzazione finale dovrebbe essere simile a questa e, chiaramente, puoi modificare i valori come meglio preferisci.
Mostrare soltanto le etichette dati utili
Per mostrare i punteggi:
- Seleziona il grafico.
- Apri Progettazione grafico > Aggiungi elemento grafico.
- Seleziona Etichette dati.
- Nel riquadro di formattazione, lascia attiva soltanto l'opzione Valore.
- Disattiva Nome serie e Nome categoria.
A questo punto comparirebbe anche il valore 100 sui Paesi non selezionati. Per nasconderlo, utilizziamo un formato numero personalizzato.
Nella sezione Numero delle etichette inserisci:
[>100]#;;;
Il formato mostra soltanto i numeri superiori a 100. Tutti i valori artificiali vengono quindi nascosti, anche se restano presenti nella serie.
Applichiamo poi questa formattazione alle etichette:
- carattere: Segoe UI;
- dimensione: 16 pt;
- grassetto;
- colore: bianco;
- riempimento: nessun riempimento;
- contorno: nessun contorno.
Personalizzare i confini dei Paesi
Nel file, i confini tra i Paesi vengono resi più evidenti con una linea puntinata.
- Seleziona la serie della mappa.
- Apri Riempimento e linea.
- Imposta il contorno su linea continua di colore nero.
- Imposta la larghezza a circa 3 pt.
- Scegli un tipo di tratteggio puntinato.
Il riempimento dei Paesi continua a dipendere dalla scala colori impostata nella sezione precedente. La linea serve soltanto a separare visivamente le aree.
Per il bordo esterno dell'area del tracciato puoi utilizzare:
- linea nera;
- larghezza di circa 1,5 pt;
- nessun riempimento aggiuntivo.
Formattare lo sfondo del grafico
Seleziona l'area esterna del grafico e imposta:
- Riempimento pieno: #F2F2F2;
- Bordo: nessuna linea.
Lo stesso grigio viene utilizzato come colore minimo della scala. In questo modo i Paesi non selezionati si integrano con lo sfondo, mentre i confini puntinati ne mantengono leggibile la forma.
Formattare il titolo del grafico
Il titolo presente nel file è: Competenza in inglese in Europa: EF EPI 2025.
La formattazione utilizzata è:
- carattere: Segoe UI;
- dimensione: 60 pt;
- grassetto;
- colore: #595959;
- allineamento: centrato;
- posizione: sopra il grafico.
La dimensione può sembrare elevata, ma è proporzionata al grafico molto ampio utilizzato nel foglio GRAFICO_MAPPA. Togliamo la legenda: la scala cromatica rappresenta un valore continuo e le etichette mostrano già i punteggi necessari.
Come verificare il filtro dinamico della mappa
Dopo avere completato la formattazione, prova le diverse opzioni presenti in B3.
Visualizzare tutti i Paesi
- tutti i Paesi mantengono il punteggio reale;
- tutte le etichette sono visibili;
- la cella C3 restituisce 36;
- la scala colori confronta l'intero insieme dei dati
Filtrare la mappa per livello di competenza
- i Paesi della fascia mantengono il punteggio reale;
- gli altri Paesi ricevono il valore 100;
- i valori 100 non vengono mostrati nelle etichette;
- i Paesi esclusi assumono il colore grigio chiaro;
- l'estensione geografica della mappa non cambia
Come adattare il grafico a mappa ad altri dati
Lo stesso ragionamento può essere utilizzato per rappresentare:
- fatturato per area geografica;
- numero di clienti per regione;
- copertura commerciale per Paese;
- indicatori di rischio;
- stato di avanzamento di un progetto internazionale;
- fasce di performance definite dall'utente.
Servono sempre due elementi, massimo tre, per avere un buon risultato con i grafici a mappa in Excel:
- una colonna geografica riconoscibile da Excel;
- un valore numerico reale da mostrare;
- un valore artificiale esterno alla scala, usato per mantenere visibili le aree escluse.
Nel file abbiamo utilizzato 100 come valore neutro e 400 come minimo della scala. In un altro caso dovrai scegliere valori coerenti con l'intervallo reale dei tuoi dati.
Per esempio, se i valori reali fossero percentuali comprese tra 40% e 90%, potresti assegnare 0% agli elementi esclusi e impostare il minimo della scala a 40%.
Grafico a mappa dinamico in Excel: riepilogo finale
Abbiamo visto come creare un grafico a mappa in Excel, aggiungere un filtro dinamico e personalizzarne colori, etichette, sfondo e contorni.
Il passaggio decisivo consiste nel non rimuovere i Paesi che non rispettano il filtro. La formula mantiene tutte le aree geografiche e sostituisce i valori esclusi con 100. La scala colori e il formato delle etichette trasformano poi questo valore tecnico in un elemento neutro e invisibile.
In sintesi:
- il menu a discesa controlla la fascia da mostrare;
- la formula in B6 prepara un intervallo sempre della stessa altezza;
- il valore 100 mantiene stabile la mappa;
- il minimo a 400 assegna ai Paesi esclusi un colore neutro;
- il formato [>100]#;;; nasconde le etichette non necessarie.
Un'alternativa, consigliata da Roberto Mensa (che ringrazio), poteva essere quella di utilizzare i filtri dati (slicer) per arrivare allo stesso risultato - chissà che una versione 2 di questa guida non la includa!
Scarica il file, modifica la selezione in B3 e prova ad adattare il metodo a un altro indicatore geografico!
Sono un formatore e consulente esperto nell’uso e nell’insegnamento di Microsoft Excel. Microsoft MVP in Excel dal 2024.
Negli ultimi 3 anni ho tenuto corsi presso realtà in multinazionali come Aruba, Bridor, IMI Orton, Primadonna e SISAL, oltre a PMI e startup di diverso genere.
Realizzo corsi di formazione Excel dedicati per aziende, supporto professionisti 1:1 a distanza con call mirate e collaboro con aziende offrendo servizi di consulenza quali creazione di business plan, dashboard di vendita e non solo.
Vuoi saperne di più? Prenota una call gratuita di 15′!