Calcolare riscatto laurea Excel

    Calcolare_Riscatto_Laurea_Microsoft_Excel_Riassunto

    Scopriamo come calcolare il riscatto della laurea tramite un file Excel, in particolare parleremo del riscatto della laurea “light” o “agevolato” che prevede un notevole recupero fiscale rispetto alla procedura standard di riscatto. Questa possibilità rimarrà in vigore fino alla fine del 2021 e sarà potenzialmente prorogata ulteriormente.

    Scopri direttamente quanto costa riscattare la laurea con il file interattivo!

    Se vuoi scoprire più nel dettaglio come funzioni il riscatto della laurea, ti suggerisco di dare un occhio al sito dell’INPS dato che in questa sede parleremo di come calcolarlo e non della parte normativa. L’articolo è stato creato in collaborazione con lo studio Giussani Consulting, che ha supportato nella parte di revisione sui calcoli effettuati.

    Se preferisci scaricare il file per calcolare il riscatto della laurea in autonomia, clicca sul pulsante successivo e il download partirà in automatico!

    Quali sono i dati necessari per calcolare il riscatto della laurea

    Calcolare_Riscatto_Laurea_Microsoft_Excel_Riassunto

    Per calcolare il riscatto della laurea e verificarne la convenienza, ci servono i seguenti dati:

    • Retribuzione dell’ultimo anno lorda: fondamentale per il calcolo dell’IRPEF
    • Anni di laurea da riscattare: quanti siano gli anni totali di laurea che desideriamo riscattare
    • Anni di rimborso: in quanti anni vogliamo restituire l’investimento, con quote mensili
    • Quota annuale: qual è la quota annuale, decisa dall’INPS, per il rimborso di un singolo anno (in questo caso pari a € 5.264,49)

    Dobbiamo inoltre recuperare la quota fissa e variabile dell’IRPEF, che si può ottenere facilmente dal sito dell’Agenzia delle entrate. Questa parte andrà a comporre una tabella per effettuare il nostro calcolo e deve essere posta in ordine crescente di tassazione percentuale (dalla fascia più bassa a quella più alta) per permetterci di utilizzare correttamente la funzione CERCA.VERT.

    Come calcolare il costo complessivo del riscatto della laurea

    Iniziamo con il calcolare il totale di quanto dovremo versare per il riscatto della laurea, ipotizzando uno stipendio pari a 27.500,00 € nell’anno precedente. Inseriamo quindi i seguenti valori:

    • Retribuzione dell’ultimo anno lorda: 27.500,00 €
    • Anni di laurea da riscattare: 5
    • Anni di rimborso: 10
    • Quota annuale: € 5.264,49

    Iniziamo con i calcoli, vedendo il totale da versare:

    Totale da versare = Anni laurea da riscattare * Quota per Anno da riscattare

    F3 = $C4*$C6 = 26.322,45 €

    Dividiamo poi il totale da versare per il numero di anni che abbiamo considerato per il rimborso:

    Totale annuo = Totale da versare / Anni di rimborso

    F4 = F3/$C5 = 2.632,25 €

    Troviamo poi la nostra quota mensile di rimborso per il riscatto della laurea:

    Quota mensile = Totale annuo da versare / 12

    F5 = F4/12 = 219,35 €

    Calcolo quota fissa IRPEF (senza riscatto della laurea)

    Calcolare_Riscatto_Laurea_Excel_IRPEF_Senza_Riscatto

    Calcoliamo poi l’imposta lorda IRPEF senza il riscatto della laurea. In questo caso abbiamo necessità di sommare due valori diversi, ovvero la quota fissa e quella variabile.

    Imposta lorda IRPEF senza riscatto

    =SOMMA(CERCA.VERT($C3;$H$3:$K$7;4;VERO);

    CERCA.VERT($C3;$H$3:$J$7;3;VERO)*($C3-(CERCA.VERT($C3;$H$3:$H$7;1;VERO))))

    F6 = 6.824,73 €

    Vediamo la formula nel dettaglio, in modo da seguire i singoli passaggi con semplicità.

    La quota fissa è calcolata con un semplice CERCA.VERT sulla tabella relativa all’IRPEF partendo dalla retribuzione lorda dell’anno precedente, ma dobbiamo ricordarci di inserire il parametro VERO anzichè FALSO alla fine della formula. Questo è necessario perchè il nostro valore di ricerca, cioè lo stipendio, potrebbe anche non esistere nel database di partenza. Inserendo FALSO, il CERCA.VERT non funzionerebbe correttamente. Se vuoi approfondire, puoi scoprire di più sulla funzione CERCA.VERT cliccando qui.

    In particolare, se il valore dello stipendio non è presente nella tabella dell’IRPEF, CERCA.VERT restituirà il valore inferiore al nostro stipendio più vicino, prendendo come riferimento gli scaglioni IRPEF. Ad esempio, uno stipendio di 27.500 € rientrerebbe nella fascia 15.001 € – 28.000 € e non in quella successiva, 28.001 € – 55.000 €. CERCA.VERT cercherebbe quindi il riferimento di € 15.001 per ottenere la quota fissa corrispondente, che si trova sulla quarta colonna nella nostra tabella:

    = CERCA.VERT($C3;$H$3:$K$7;4;VERO)

    Sempre con l’esempio di 27.500 €, il passaggio sarebbe:

    1. CERCA.VERT($C3;$H$3:$K$7;4;VERO)
    2. CERCA.VERT(27.500 €;$H$3:$K$7;4;VERO) > troviamo qual è il valore inferiore più vicino a 27.500 €
    3. CERCA.VERT(15.001 €;$H$3:$K$7;4;VERO) > troviamo il risultato nella quarta colonna
    4. Totale quota fissa = 3.450,00 €

    A questa quota fissa andrà poi aggiunta la quota variabile.

    Calcolo quota variabile IRPEF (senza riscatto della laurea)

    Calcolare_Riscatto_Laurea_Excel_IRPEF_Con_Riscatto

    La quota variabile viene anch’essa calcolata utilizzando CERCA.VERT e VERO- anche in questo caso, vogliamo trovare la quota IRPEF variabile da aggiungere se il nostro stipendio è pari a € 27.500 €.

    Vediamo quindi la formula che trova la percentuale di tassazione dello scaglione che ci interessa e poi la moltiplica per la differenza fra lo stipendio meno il valore dello scaglione corrispondente

    = CERCA.VERT($C3;$H$3:$J$7;3;VERO)*($C3-(CERCA.VERT($C3;$H$3:$H$7;1;VERO)))

    Vediamo come funziona nel dettaglio:

    1. CERCA.VERT($C3;$H$3:$J$7;3;VERO)*($C3-(CERCA.VERT($C3;$H$3:$H$7;1;VERO)))
    2. CERCA.VERT(27.500 €;$H$3:$J$7;3;VERO)*(27.500 € -(CERCA.VERT(27.500 €;$H$3:$H$7;1;VERO))) > la prima parte ci serve per calcolare la percentuale, mentre la seconda effettua la differenza fra lo stipendio e l’inizio dello scaglione
    3. CERCA.VERT(15.001 €;$H$3:$J$7;3;VERO)*(27.500 €-15.001 €) > non ci resta che trovare il primo valore, cioè la percentuale, e moltiplicarlo per la differenza
    4. Totale quota variabile = 27%*12.499 € = 3.374,73 €

    A questo punto non ci resta che sommare i due valori con la funzione SOMMA, come visto in precedenza: il totale sarà quindi pari a 3.500 € + 3.374,73 € = 6.824,73 €

    Imposta lorda IRPEF senza riscatto

    =SOMMA(CERCA.VERT($C3;$H$3:$K$7;4;VERO);CERCA.VERT($C3;$H$3:$J$7;3;VERO)*($C3-(CERCA.VERT($C3;$H$3:$H$7;1;VERO))))

    F6 = 6.824,73 €

    Come calcolare il risparmio fiscale del riscatto della laurea

    Calcolare_Riscatto_Laurea_Excel_Risparmio_Fiscale_Annuo_Complessivo

    A questo punto sappiamo quale sarà il nostro IRPEF annuale senza il riscatto della laurea.

    Essendo i contributi versati per il riscatto di laurea oneri deducibile ai sensi l’articolo 10 , lettera e, del TUIR ( quindi si possono portare direttamente in diminuzione del reddito imponibile), dobbiamo procedere al calcolo della nuova base imponibile di imposta. Questa nuova base imponibile IRPEF è fondamentale per calcolare la convenienza del riscatto:

    Imponibile IRPEF = Retribuzione ultimo anno lorda – totale annuo da versare per il riscatto

    F7 = C3-F4 = 24.867,76 €

    Possiamo poi replicare la struttura vista in precedenza per il calcolo dell‘IRPEF, avendo l’accorgimento di considerare il nuovo imponibile e non la retribuzione dell’anno precedente perchè stiamo considerando il caso di riscatto della laurea. In più, togliamo 1 € dal calcolo finale per uniformare gli scaglioni:

    IRPEF annuale con riscatto

    =SOMMA(CERCA.VERT(F7;$H$3:$K$7;4;VERO);

    CERCA.VERT(F7;$H$3:$J$7;3;VERO)*(F7-(CERCA.VERT(F7;$H$3:$H$7;1;VERO)-1)))

    F8 = 6.114,29 €

    A questo punto possiamo verificare la convenienza del riscatto della laurea, dato che:

    Risparmio annuo = IRPEF annuale (senza riscatto) – IRPEF annuale (con riscatto)

    F10 = F6-F8 = 710,44 €

    In questo caso, ad esempio, il nostro risparmio in termini fiscali è di 710,44 €. Questo succede perchè, anche se versiamo in totale 2.632,25 € per il riscatto, finiremo comunque con spendere 710,44 € in meno di IRPEF a fine anno, compensando parzialmente il nostro contributo. In totale, spenderemo infatti 2.632,25 € – 710,44 € = 1.921,81 € per ogni anno di contribuzione.

    Possiamo anche vedere il risparmio in forma percentuale:

    Risparmio annuo % = Risparmio annuo / Totale annuo

    F11 = F10/F4 = 26,99%

    In questo caso, ad esempio, abbiamo il 26,99% di risparmio annuo a livello percentuale. Possiamo poi moltiplicarlo per i 10 anni considerati, ottenendo il valore finale di risparmio rispetto al contributo che daremo per il riscatto:

    Risparmio totale = Risparmio annuo * Numero di anni di rimborso

    F12 =F10*$C5 = 7.104,36 €

    Riepilogo del riscatto della laurea light o agevolato

    Siamo arrivati alla conclusione della guida!

    Spero che il file possa aiutarti per decidere se effettuare il riscatto della laurea, puoi scaricarlo dal pulsante che trovi qui sotto nel caso volessi fare qualche prova.

    I calcoli sono gli stessi descritti nella guida, dove probabilmente l’elemento più interessante (lato Excel) è dato dall’utilizzo di CERCA.VERT con VERO, visto che nella stragrande maggioranza dei casi (ad esempio lavorando con anagrafiche) la funzione viene utilizzata con FALSO, indicando che il valore utilizzato nel CERCA.VERT è presente nella tabella di ricerca.

    Lascia un commento

    Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *