Calendario Excel 2027

Creare un calendario 2027 con Microsoft Excel è possibile in tanti modi diversi, che dipendono anche dalla tua abilità con Excel.

Può essere essere comodo avere un calendario personalizzato ma, se vuoi risparmiare tempo senza creare una struttura eccessivamente complessa, Microsoft supporta la creazione di calendari con diversi template già compilati e gratuiti, cui possiamo accedere aprendo Excel e cliccando su File > Nuovo. Da lì basta seguire una veloce procedura, che racconto nella seconda parte dell'articolo. Vedremo anche come creare un calendario completo per il 2027 con Copilot!

Se vuoi scaricare il calendario Excel compatibile con tutte le versioni (fino a Excel 2010), clicca qui:

Se vuoi scaricare direttamente un calendario per il 2027 clicca sul pulsante successivo (compatibile con Excel online e Excel 365):

Il formato è piuttosto semplice, ma è già ottimizzato per la stampa presentando 2 mesi per ogni pagina e un layout minimale per permetterti di prendere note facilmente una volta stampato.

Per i calendari precedenti fai riferimento ai link seguenti:

• Scarica il calendario Excel 2026
• Scarica il calendario Excel 2025
• Scarica il calendario Excel 2024
• Scarica il calendario Excel 2023
• Scarica il calendario Excel 2022
• Scarica il calendario Excel 2021
• Scarica il calendario Excel 2020

Clicca qui invece se stai cercando anche un file dedicato per il piano ferie su Excel.

Calendario Excel 2027 Modificabile

Il formato del calendario 2027 presenta sia i giorni della settimana sia i singoli mesi, giusto per aiutare la comprensione. Puoi modificarlo come preferisci, dipende sempre da quale sarà il tuo utilizzo primario e quante volte ti capiterà di doverlo aggiornare - ad esempio potresti voler allargare le colonne o mettere i singoli mesi su fogli singoli.

Calendario 2027 PDF stampabile

Lo stesso file visto in precedenza può essere stampato facilmente, dato che avrai tutti i mesi in 6 diversi fogli. Puoi evitare di fare ulteriori operazioni cliccando direttamente sul pulsante seguente:

Nel caso volessi prima modificare il file Excel per poi salvarlo in PDF, puoi seguire la seguente procedura:

• File
• Salva con nome
• Selezionare PDF con il nome prescelto
• Salvare

L'indicazione PDF è fra le ultime del sistema, ma dovresti trovarla senza troppe difficoltà.

Il file presenta anche un formato ancora più essenziale per permetterti di stampare il calendario in un colpo solo, lo trovi nel foglio CALENDARIO:

Questo formato potrebbe esserti utile per avere un'idea di massima della progressione nell'anno, benchè lo spazio sia limitato per prendere appunti.

Come creare il calendario Excel 2027 con la funzione Sequenza

Per questo foglio ho preso ispirazione da un ottimo video di Leila Gharani che spiega come si può utilizzare la funzione SEQUENZA per creare un calendario da zero.

NB: Questa funzione è compatibile esclusivamente con la versione 365 e successive, ma puoi accedere allo stesso calendario dal foglio "UNA_PAGINA" se lo desideri.

Vediamo prima di tutto com'è composta la funzione SEQUENZA:

=SEQUENZA(righe;[colonne];[inizio];[passaggio])

SEQUENZA è una funzione matriciale, quindi basta scriverla una sola volta e riempirà automaticamente le celle necessarie, riconoscibili dal bordo azzurro. "Righe" indica quante righe coprire, "Colonne" quante colonne, "Inizio" il primo valore della sequenza e “Passaggio” lo scarto tra i numeri. Ad esempio:

=SEQUENZA(10;5;1;2)

Questa formula genera 50 valori in un blocco di 10 righe per 5 colonne. Avendo inizio = 1 e passaggio = 2 la sequenza diventa 1, 3, 5, 7 e così via.

Nel caso specifico:

=SEQUENZA(53;7;46385;1)

I numeri inseriti, come notiamo sono 4. Nel dettaglio:

• 53 indica il numero di righe, ovvero le 53 settimane dell'anno
• 7 indica il numero di colonne, ovvero i giorni della settimana
• 46385 è (in formato numero) la data pari al giorno 29/12/2026, dato che il 2027 non inizia di lunedì
• 1 è la distanza che ci interessa, dato che fra i giorni deve esserci solo 1

La funzione partirà quindi dal 1 Gennaio e aggiungerà un giorno fino ad arrivare a 371 giorni più avanti (53*7), riempiendo le celle che abbiamo indicato.

Nota di formattazione: vediamo che le ultime cifre non sono però visualizzate sul foglio. Il motivo è che ho inserito un altro formato ( ;;; ) che nasconde il contenuto all'interno delle celle stesse. Per verificarlo, puoi cliccare su Home e poi andare nella sezione Numeri, cliccando sulla freccia in basso a destra nella sezione dedicata.

Come inserire la formattazione condizionale nel calendario Excel 2027

Vediamo che il primo giorno del mese è sempre giallo con un bordo nero. Questo accorgimento visivo è stato realizzato con la formattazione condizionale, utilizzando la funzione GIORNO dato che tutti i valori sono in formato data. Puoi andare su Home > Formattazione Condizionale > Gestisci Regole per modificarla o, nel caso non ti piacesse, rimuoverla del tutto.

Come creare il calendario Excel 2027 Mensile

Possiamo realizzare un calendario 2027 mensile utilizzando varie funzioni, che ci permetteranno di vedere, in autonomia, quali siano i giorni dell'anno in un singolo mese.

Nella prima versione, l'utente deve inserire un parametro solo, cioè l'anno considerato: in questo caso, 2027. Sapendo che i mesi sono 12, creeremo la sequenza dei mesi e poi avremo la nostra distribuzione, proprio sotto i singoli mesi.

Vediamo più nello specifico cosa succede nella cella D3:

=SEQUENZA(;12)

Questa formula crea una sequenza {1,2,3,4,5,6,7,8,9,10,11,12}, i cui valori si distribuiranno su diverse colonne. Useremo poi il numero del mese per segmentare le singole date

A questo punto, riutilizzeremo la sequenza per la nostra formula:

=LET(start;DATA(D2;1;1);
end;DATA.MESE(start;12);
seq;SEQUENZA(end-start;;start);
red;REDUCE("";D3#;LAMBDA(acc;v;STACK.ORIZ(acc;FILTRO(seq;MESE(seq)=v))));
final;SE.ERRORE(ESCLUDI(red;;1);"");
final)

Vediamo i singoli passaggi prima del calcolo finale:

• start rappresenta il primo giorno dell'anno che abbiamo indicato nella cella D2, cioè 2027. La funzione DATA ricrea una data a partire dall'anno, che sarà 01/01/2027
• end indica invece il primo giorno dell'anno successivo. Riprendendo la data in start, aggiungiamo direttamente 12 mesi con DATA.MESE e quindi questa data diventerà il giorno 01/01/2027
• seq segnala quanti siano i giorni dell'anno. Questo perchè creiamo una SEQUENZA che fa la differenza fra i due valori, partendo poi dal valore start (01/01/2027) per creare la sequenza. Avremo quindi tutte le date così composte, fino alla fine dell'anno {01/01/2027, 02/01/2027, 03/01/2027 ...31/12/2027}

A questo punto, abbiamo tutti gli elementi e arriviamo a red, che è la sezione più complessa di questa formula. REDUCE ci permette di creare un calcolo iterativo, dove partiamo dal valore vuoto ("") e poi vogliamo fare un'operazione per tutti valori considerati nella sequenza D3#, che non è altro che la nostra sequenza di mesi da 1 a 12. REDUCE ci richiede poi due diversi parametri: acc sarà l'accumulatore, mentre v sarà il valore. In sostanza, noi vogliamo fare un calcolo 12 volte: vedere, per ognuno dei mesi, quali siano quelli che sono parte di un certo mese. Visto che c'è un'iterazione, avremo un risultato alla fine di ognuno dei valori della sequenza D3#, che diventerà l'accumulatore. Quindi prima avremo il valore vuoto, poi avremo un risultato per il valore 1, che diventerà l'accumulatore. Poi avremo il risultato per il valore 2, che diventerà l'accumulatore successivo, e così via, fino al 12.

Ora, l'aspetto importante è sapere che a noi, in questo caso, l'accumulatore interessa parecchio. Questo perchè noi vogliamo assolutamente tracciare i casi nei quali il mese delle date è pari a 1, per vederlo poi sotto il valore 1 dei mesi. Lo stesso vogliamo fare per le date nelle quali il mese è pari a 2, per vedere anche loro sotto il valore 2 dei mesi (fino a 12). Il modo nel quale possiamo salvare questo dato è quindi creando uno stack, dove con STACK.ORIZ stiamo dicendo che vogliamo impilare orizzontalmente dei dati. Ma quali?

Vogliamo impilare orizzontalmente l'accumulatore e poi, per ognuno dei valori (v), ricavare, con FILTRO, i giorni nei quali il MESE è pari a quello del nostro array D3#. In sostanza, Excel, così facendo, salva l'accumulatore e poi, mano a mano, calcolerà il risultato successivo, permettendoci di averli tutti ordinati uno dopo l'altro.

Vediamo come funziona REDUCE più nel dettaglio, distinguendo accumulatore e valore:

• STEP1: il primo accumulatore è "". Quindi avremo =STACK.ORIZ("";FILTRO(seq;MESE(seq)=1;"")). Il risultato sarà un'intera colonna di valori vuoti ("") e poi le date del mese di Gennaio, dato che stiamo filtrando quando il mese è 1
• STEP2: il secondo accumulatore è con i dati del mese di Gennaio. Avremo quindi =STACK.ORIZ({"",date_gennaio};FILTRO(seq;MESE(seq)=2;"")). Stavolta avremo l'intera colonna con i vuoti, poi una colonna con i valori di Gennaio, poi un'altra colonna con i valori di Febbraio

Il procedimento si ripete fino al valore 12, permettendoci quindi di salvare, per ogni passaggio, le date collegate con il mese prestabilito. A questo punto, creiamo un array che ha tutti i valori che ci interessano.

Siamo quasi alla fine ma a quanto punto, però, ci serve final per due motivi principali. Il primo è che abbiamo una colonna inutile composta solo di valori vuoti. Il secondo è perchè non tutti i mesi hanno lo stesso numero di giorni - e se non facciamo niente, vedremo dei fastidiosi errori. A questo punto possiamo quindi rimuovere, con ESCLUDI, la prima colonna del nostro array finale. Con SE.ERRORE, invece, trasformiamo gli errori in un valore vuoto, in modo da aiutare la visualizzazione.

A questo punto, la nostra formula è completata - e, con pochi accorgimenti, potremmo creare un calendario personalizzato per qualsiasi anno vogliamo sul nostro file Excel!

Come visualizzare il weekend sul calendario Excel 2027

Notiamo che, nel calendario Excel mensile 2027, abbiamo i valori per sabato e domenica con uno sfondo blu. Questo aspetto grafico è facilmente personalizzabile, basta selezionare l'intervallo per poi digitare:

=GIORNO.SETTIMANA(D4;2)>=6

Stiamo dicendo a Excel che vogliamo visualizzare diversamente tutte le date che abbiano un giorno della settimana che sia sabato (6) o domenica (7). Bisogna fare attenzione con queste funzioni perchè, senza il 2, prenderemmo una settimana che per noi ha poco senso (domenica-sabato anzichè lunedì-domenica).

Template Microsoft Excel calendario 2027

Se vogliamo invece utilizzare i template di Microsoft, come dicevamo dovremo andare su File > Nuovo per iniziare la nostra ricerca. Successivamente, dovremo inserire la parola "calendario" nella ricerca:

A questo punto avremo una folta lista di template già creati, parliamo di oltre 50 possibilità. Volendo, si possono anche sfogliare online:

A questo punto non ci resta che scegliere quello più adatto a noi e salvarlo come nuovo file. Tutti i template sono modificabili e possono utilizzare strumenti di Excel quali le tabelle, molto utili nel caso dovessimo fare aggiornamenti.

Nel caso volessi scaricare il file che trovi all'inizio dell'articolo, puoi cliccare sul pulsante successivo:

Come creare il calendario Excel 2027 con COPILOT

Copilot è migliorato moltissimo ed è ora possibile utilizzarlo anche per funzionalità quali la creazione di un calendario in Excel. In questo caso parliamo della versione di Copilot a pagamento (nota importante).

Apriamo la schermata di Copilot per poi utilizzare questo prompt:

crea un calendario mensile per il 2027 di facile consultazione in un foglio chiamato CALENDARIO_2027_COPILOT

Abbiamo gli elementi per partire, dato che la richiesta è chiara e definiamo anche dove ottenere il nostro calendario.

Copilot si prenderà del tempo per rispondere al meglio alla nostra richiesta, fornendo commenti testuali per ogni step del processo.

Al termine, Copilot ci comunica di aver creato un calendario di 12 mesi utilizzando delle funzioni e ci fornisce la spiegazione. Cliccando su FINE stiamo validando quanto fatto dall'AI, che apparirà quindi sul nostro foglio.

Quando Copilot interviene, nota come ci sia questa colorazione arcobaleno e un punto verde prima del nome del foglio - finchè non diremo "Fine", queste modifiche non saranno confermate.

Questo è il risultato finale, piuttosto chiaro, pulito e, soprattutto, corretto.

A questo punto possiamo esplorare la funzione utilizzata da Copilot per i singoli mesi, probabilmente influenzata anche dalla personalizzazione del mio account:

=LET(first;DATA(2027;1;1);startDate;first-GIORNO.SETTIMANA(first;2)+1;days;SEQUENZA(6;7;startDate;1);SE(MESE(days)=1;days;""))

La formula creata da Copilot per creare il calendario in Excel ha senso? Sì, ha senso:

• first: la funzione utilizza correttamente LET per definire la prima data del mese
• startDate: riutilizza first per recuperare il lunedì precedente al primo giorno del mese, se non è un lunedì (caso di Febbraio o Marzo). Ad Aprile, per esempio, è un giovedì. Quindi la funzione dice: prendi 01/04/2027, togli 4 giorni (giovedì = 4' giorno della settimana) e aggiungi 1, ottenendo il lunedì della settimana (29/03/2027) che si interseca poi con il 01/04/2027. La soluzione è piuttosto elegante
• days indica quanti giorni considerare e qui andiamo larghissimi, perchè abbiamo 6 righe x 7 colonne = 42 celle potenziali, probabilmente per una questione di layout, a partire dalla nostra startDate. Ci sarà sempre dello spazio libero, ma almeno in questo modo copre tutti i casi limite tipo Agosto, che va su ben 6 righe
• ultimo check dice che se il mese di days è il mese corrente (qui parliamo di Gennaio quindi 1), otteniamo days, altrimenti vuoto, che è la visualizzazione standard per date che non sono del mese

Quindi la formula genera le giornate del mese e quelle immediatamente successive e precedenti, ma le date non appartenenti al mese diventano vuote. Avrei preferito avere anche quest'ultimo passaggio inserito in LET, tipo:

=LET(first;DATA(2027;1;1);startDate;first-GIORNO.SETTIMANA(first;2)+1;days;SEQUENZA(6;7;startDate;1);final;SE(MESE(days)=1;days;"");final)

Sono comunque dettagli, il risultato è interessante e senza alcun passaggio manuale da parte nostra!