Contare celle intervallo date Excel

Usando Microsoft Excel, contare il numero di celle all'interno di un intervallo di date può sembrare complesso, in particolare quando non consideriamo la fine del mese ma i valori in mezzo al calendario. Ti è mai successo di voler contare le celle fra due intervalli, magari in anni diversi?

In questa guida vediamo numerosi casi pratici che puoi anche scaricare dal file dedicato!

Come contare le celle di un intervallo date definito su Excel

Ecco come fare, con due semplici funzioni combinate assieme.

Formula generale:

CONTA.PIÙ.SE([intervallo_date];">="&DATA([anno;mese;giorno]);[intervallo_date];"<="&DATA([anno;mese;giorno]))

Primo esempio: abbiamo una serie di date nell'intervallo C3:C21 e vogliamo sapere quali siano nell'anno 2017. Consideriamo quindi:

- [intervallo_date] = C3:C21

- Primo [anno;mese;giorno]: 2017;1;1 (essendo il primo giorno da considerare)

- Secondo [anno;mese;giorno]: 2017;12;31 (essendo l'ultimo giorno da considerare)

Formula pratica:

CONTA.PIÙ.SE(C3:C21;">="&DATA(2017;1;1);C3:C21;"<="&DATA(2017;12;31))

Secondo esempio: abbiamo una serie di date nell'intervallo C3:C21 e vogliamo sapere quali siano dal primo Febbraio al primo Ottobre 2016. Consideriamo quindi:

- [intervallo_date] = C3:C21

- Primo [anno;mese;giorno]: 2016;2;1 (essendo il primo giorno da considerare)

- Secondo [anno;mese;giorno]: 2016;10;1 (essendo l'ultimo giorno da considerare)

Formula pratica:

CONTA.PIÙ.SE(C3:C21;">="&DATA(2016;2;1);C3:C21;"<="&DATA(2016;10;1))

Come contare le celle in Excel con date in diverse colonne

Vediamo adesso come contare le celle di Excel che hanno delle date e rispettano due condizioni. In questo caso vogliamo considerare la nostra tabella chiamata TBL_DIPENDENTI che ha tre diverse colonne:

• Nome del dipendente
• Data di entrata
• Data di uscita

Vogliamo sapere, a una certa data, quanti fra i dipendenti siano attivi in organico.

Vediamo la formula che ci serve:

=CONTA.PIÙ.SE(TBL_DIPENDENTI[ENTRATA];"<="&F3; TBL_DIPENDENTI[USCITA];">="&F3)

F3 è la data che ci interessa, in questo caso il 31/12/2021. Vogliamo contare tutte le righe della tabella quando la data di entrata è minore o uguale a 31/12/2021 E la data di uscita è uguale o superiore a F3. In questo modo inseriamo le due condizioni e otteniamo il valore 7, che sono i dipendenti attivi. Il valore appare come "7 Dipendenti" solo perchè c'è un formato personalizzato, puoi rimuoverlo cliccando sulla cella F5 > Home > Numeri, da qui puoi scegliere il formato che preferisci.

Vediamo anche come ottenere i nomi dei dipendenti, con una formula che funziona solo con le ultime versioni (365):

La formula ricalca la logica precedente utilizzata per il conteggio:

=FILTRO(TBL_DIPENDENTI[NOME];
(TBL_DIPENDENTI[ENTRATA]<=F3)* (TBL_DIPENDENTI[USCITA]>=F3);"")

Vogliamo restituire esclusivamente i nomi quando la data di entrata è inferiore o uguale a F3 E la data di uscita è uguale o superiore a F3. Questo viene soddisfatto dalla moltiplicazione con * che significa che entrambe le condizioni devono essere soddisfatte. Se così non è, apparirà il valore vuoto.

Come contare le celle di un dato mese su Excel

Vediamo anche un caso per contare le celle che appartengono a un dato mese, seguendo una condizione e senza creare ulteriori colonne di supporto.

Prima di tutto dobbiamo inserire nella cella E4 e successive il mese di inizio che ci interessa, quindi in questo caso da Gennaio 2021 in poi. Per visualizzare come "gen-21" basta modificare il formato della cella dalla schermata Home -> Numeri.

Vediamo ora invece la formula:

=CONTA.PIÙ.SE(C:C;$F$2;B:B;">="&E4;B:B;"<="&FINE.MESE(E4;0))

In questo caso, il CONTA.PIÙ.SE considera inizialmente solo i valori della colonna C che abbiano F2 (ovvero X). Successivamente, considera la colonna B prima prendendo solo le celle con valore maggiore o uguale a E4 (che è il 01/01/2021) per poi prendere esclusivamente le celle minori o uguali del FINE.MESE sempre di E4 (ovvero 31/01/2021). Questo ci permette di velocizzare i calcoli, per non scrivere ogni volta l'ultimo giorno del mese.

Come contare le celle comprese in un periodo su Excel senza considerare l'anno

In questo caso vogliamo contare il numero di celle che siano in un intervallo di date su Excel, ma senza considerare l'anno. Quindi se consideriamo 21/07 - 21/09, vogliamo contare tutte le celle in questo range, non solo quelle di uno specifico anno. La soluzione proposta funziona solo con Excel 365 - se non hai questa versione, puoi comunque utilizzare la versione online di Excel.

Questo caso è particolare perchè per Excel le date sono numeri, quindi bisogna fare qualche passaggio aggiuntivo per replicare la logica tipo "Prendi le date dal 21/07 al 31/07, poi l'intero mese di Agosto, poi le date dal 01/09 al 21/09".

Creiamo una tabella chiamata TBL_TEST_DATA che presenta:

• DATA: tutte le nostre date
• FATTURATO: un valore da poter sommare, giusto per fare un test
• MESE: il valore mensile per singola data
• GIORNO: il valore giornaliero per singola data
• INTERVALLO: qui inseriremo la formula per calcolare gli intervalli

Vediamo le singole formule.

=MESE([@DATA]) e =GIORNO([@DATA])

Queste due formule sono piuttosto semplici. Stiamo estraendo, per ogni riga della tabella, il valore del mese e del giorno. Vedi la chiocciola @ perchè indica che stiamo lavorando sulla stessa riga dei nostri dati iniziali. Questo assicura coerenza al nostro file.

Ora arriviamo al cuore del nostro calcolo. Prendiamo le seguenti celle, come riferimento:

• J3 è il mese di partenza, mentre J4 è il giorno di partenza. Quindi avremo 7 e 21, in questo caso: vogliamo tutte le date dal 21 di Luglio al 31 di Luglio
• K3 è il mese finale, mentre K4 è il giorno finale. Quindi avremo 9 e 21, in questo caso: vogliamo tutte le date dal 1 di Settembre al 21 di Settembre

Vediamo come trovare questi valori:

=SE(O(

([@MESE]=$J$3)*($J$4<=[@GIORNO]);

([@MESE]=$K$3)*($K$4>=[@GIORNO]);

LET(mesi;SEQUENZA($K$3-$J$3-1;1;$J$3+1;1);VAL.NUMERO(RICERCA([@MESE];mesi))));

"OK";

"NO")

Utilizziamo SE(O per definire tre diversi casi che ci possono andare bene: parte finale del primo mese, parte iniziale del mese finale, mese intero in questo intervallo.

La prima condizione con J3 e J4 verifica se il mese della riga corrente è uguale al mese in cella J3 e se il giorno della riga corrente è maggiore o uguale al giorno in cella J4. La seconda verifica se il mese della riga corrente è uguale al mese in cella K3 e se il giorno della riga corrente è minore o uguale al giorno in cella K4. Abbiamo quindi risolto il tema dei mesi potenzialmente "parziali", ma ci serve la terza condizione:

• LET dichiara che il calcolo successivo si chiamerà mesi
• SEQUENZA sta utilizzando il mese finale e quello iniziale per creare una sequenza di valori. Dato che parte da J3+1, ovvero il mese iniziale + 1, avremo una sequenza di mesi interi che ci interessa considerare
• VAL.NUMERO(RICERCA verifica che il mese della riga corrente sia compreso nella nostra sequenza. Se avessimo 7 oppure 8, questi due valori sarebbero considerati

A questo punto, vediamo che avremo OK se una delle tre condizioni è corretta, mentre avremo NO se nessuna di queste si verifica.

A questo punto possiamo trovare facilmente il totale di celle che sono in questo intervallo:

=CONTA.SE(TBL_TEST_DATA[INTERVALLO];"OK")

In questo modo contiamo tutte le celle della nostra tabella che presentano il valore OK nella nostra colonna chiamata INTERVALLO.

Ringrazio Lorenzo nei commenti per la domanda, la soluzione è stata decisamente più complessa di quanto avessi immaginato!