Eliminare duplicati Excel

    ELIMINARE_DUPLICATI_EXCEL_UNICI

    In questo articolo vediamo come eliminare i duplicati su Excel in diversi modi, sia utilizzando formule sia tramite strumenti dedicati.

    L'esempio di partenza utilizza un database con i vincitori del premio di MVP (Most Valuable Player) della NBA fino al 2018/2019, ma puoi replicare gli stessi passaggi con il file che preferisci.

    Clicca qui per scoprire invece come ordinare un elenco Excel con duplicati.

    ELIMINARE_DUPLICATI_EXCEL_INIZIO

    Excel 365: eliminare duplicati Excel con la funzione UNICI

    Nella colonna C troviamo i nomi dei giocatori vincitori del premio di MVP ma dato che alcuni giocatori hanno vinto varie volte, vogliamo creare una lista di valori univoci.

    Per ricavare la lista di valori univoci utilizzeremo la funzione UNICI. Questa funzione è stata inserita in Excel 365 e permette, in un solo passaggio, di ricavare i valori che desideriamo. Come vediamo dall'immagine, nella cella G3 inseriamo quindi la formula e otterremo la lista senza ripetizioni.

    ELIMINARE_DUPLICATI_EXCEL_UNICI

    =UNICI(C3:C66)

    Essendo la funzione UNICI una delle nuove "Excel Dynamic Arrays Functions" inserite in Excel 365, dovremo inserirla solo una volta e l'intera colonna si riempirà finchè non avrà inserito l'ultimo valore univoco. Come vediamo, l'intervallo sarà circondato da un leggero bordo blu.

    Se volessimo contare i valori unici, ci basterà utilizzare la funzione CONTA.VALORI.

    ELIMINARE_DUPLICATI_EXCEL_CONTA_VALORI

    =CONTA.VALORI(G3#)

    Il cancelletto # viene inserito in automatico quando lavoriamo con questo tipo di funzioni, dato che Excel riconosce in automatico la grandezza dell'intervallo e non necessita di una delimitazione (ad esempio G3:G70). Potremmo considerare il cancelletto come se racchiudesse tutti i valori fino in fondo alla colonna (non vuote) partendo dalla cella G3.

    Eliminare duplicati Excel con la funzione UNICI e la funzione FILTRO (una condizione)

    Proviamo a fare un ulteriore passaggio per rimuovere i duplicati. In questo caso vorremmo non solo trovare gli MVP in una lista di valori univoci, ma anche inserire solamente gli atleti americani.

    In questo caso utilizziamo sia la funzione UNICI sia la funzione FILTRO, dato che la funzione FILTRO ci aiuta proprio a effettuare una selezione dei valori di partenza rispetto alla loro nazionalità.

    ELIMINARE_DUPLICATI_EXCEL_UNICI_FILTRO

    =UNICI(FILTRO(C3:C66;E3:E66="USA"))

    In questo caso vediamo come inseriamo lo stesso intervallo di partenza pari a C3:C66. In questo caso l'intervallo viene però condizionato dall'intervallo E3:E66 che deve essere pari a USA. Se così non è, i valori non vengono considerati e quindi vediamo come solo 4 giocatori non americani abbiano vinto il premio (il valore nella riga 1 passa da 34 a 30).

    Eliminare duplicati Excel con la funzione UNICI e la funzione FILTRO (due condizioni)

    Facciamo un altro test ancora. In questo caso vogliamo sapere non solo quanti siano gli MVP americani, ma vogliamo sapere anche quanti MVP siano stati Point guard (in italiano Playmaker).

    Anche in questo caso sfruttiamo le funzioni UNICI e FILTRO, ottenendo 6 giocatori totali nella selezione.

    ELIMINARE_DUPLICATI_EXCEL_UNICI_DOPPIO_FILTRO

    =UNICI(FILTRO(C3:C66;(D3:D66="Point guard")*(E3:E66="USA")))

    Il funzionamento replica quello del caso precedente, anche se avendo molteplici condizioni dobbiamo ricordarci di moltiplicarle con il simbolo * e mettendole entrambe fra parentesi.

    Eliminare duplicati Excel con le funzioni INDICE e CONFRONTA

    Se non abbiamo a disposizione la versione Excel 365 possiamo comunque trovare i valori univoci utilizzando una combinazione di funzioni. In questo caso, utilizziamo le funzioni INDICE, CONFRONTA, CONTA.SE e SE.ERRORE e trasciniamo la formula in basso.

    ELIMINARE_DUPLICATI_EXCEL_INDICE_CONFRONTA_NO_ARRAY

    =SE.ERRORE(INDICE(DB!$C$3:$C$66;CONFRONTA(0;CONTA.SE($M$2:M2;DB!$C$3:$C$66);0));"")

    Come funziona? La funzione SE.ERRORE inserirà uno spazio vuoto nel caso siano terminati i valori univoci, mentre INDICE + CONFRONTA vengono utilizzate per trovare dei valori all'interno di un certo intervallo. In questo caso, la funzione CONTA.SE è necessaria per avere risultati che non si ripetano ma richiede un approfondimento perchè è un po' complicata come funzionamento.

    Nella cella M4, come vediamo, inseriamo $M$2:M2 per permettere di avere un ampliamento dei parametri per effettuare il conteggio. In questo caso stiamo confrontando 0 con una serie di 0 poichè, tramite il CONTA.SE, stiamo contando quante volte il valore in M2 (UNICI) sia ripetuto nell'elenco iniziale dei giocatori.

    A questo punto Excel lavora con la funzione CONFRONTA per evidenziare la prima volta che troviamo lo 0 nell'intervallo iniziale. In questo caso, la cella è la cella in C3 che è pari a Bob Pettit.

    Che cosa succede nella cella M5? In questo caso stiamo confrontando sempre uno 0 contando quante volte troviamo sia il valore UNICI (M2) sia il valore Bob Pettit (M3) dato che l'intervallo è diventato $M$2:M3. Quindi eliminiamo tutte le volte nelle quali troviamo il valore Bob Pettit e otteniamo il nuovo valore univoco, ovvero Bob Cousy che si trova nella cella C4.

    Se la formula non funziona, potresti dover inserire la formula inserendola come array. Nella versione con array, dobbiamo ricordarci di inserire la formula non con ENTER bensì con CTRL + SHIFT + ENTER. Su alcuni articoli inglesi questa combinazione è chiamata CSE Array.

    ELIMINARE_DUPLICATI_EXCEL_INDICE_CONFRONTA_ARRAY

    Come notiamo, la formula inserita come array ha anche le parentesi graffe {} all'inizio e alla fine della formula. Purtroppo le formule con array risultano un po' complicate da utilizzare, dato che un utente inesperto potrebbe inserirle normalmente compromettendo il corretto funzionamento del file.

    In questo caso, per contare i valori univoci dovremo contare tutti i valori rimuovendo le celle vuote con le funzioni CONTA.VALORI e CONTA.VUOTE.

    ELIMINARE_DUPLICATI_EXCEL_CONTARE

    =CONTA.VALORI(M3:M39)-CONTA.VUOTE(M3:M39)

    Eliminare duplicati Excel con Rimuovi Duplicati

    Excel presenta anche uno strumento dedicato per cancellare i duplicati da un elenco chiamato Rimuovi Duplicati. Per utilizzarlo, dobbiamo prima di tutto copiare i valori di partenza nell'intervallo da O3 in poi. Come notiamo dalla cella O1, i valori iniziali sono 64 e quindi vi sono numerosi duplicati.

    ELIMINARE_DUPLICATI_EXCEL_ELENCO_RICOPIATO

    Per rimuovere i duplicati e accedere alla sezione dedicata dobbiamo cliccare su Dati -> Rimuovi duplicati.

    ELIMINARE_DUPLICATI_EXCEL_DATI_RIMUOVI_DUPLICATI

    Excel ci permetterà di selezionare la colonna. Appare 64 poichè è il numero di elementi totali della lista, ma è solo un dettaglio quindi possiamo cliccare su OK.

    ELIMINARE_DUPLICATI_EXCEL_SELEZIONE_COLONNE

    In questo caso siamo riusciti quindi a rimuovere i duplicati senza utilizzare formule. Come notiamo dall'immagine, i valori univoci sono sempre 34 come nei casi precedenti.

    ELIMINARE_DUPLICATI_EXCEL_FINALE

    Lascia un commento

    Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *